I need felp with creating a simple maze?

[Wayne Rayner]

it works odama but now i come to a problem which is
How do i make the ball move faster

this the last part of the code which I added but it still isn't making the ball move faster?

if ScanKeyDown (VK_Down) then
bally = bally + 1
endif
SprSetPos (ballx, bally)
DrawText ()
Sleep (75)
wend

If anyone knows how to fix it i will be happy. Also it may be working fast on your computer and really slowly on my computer.

Also I Have an example of how to do collision detection from "How to Write Games in b4GL" and it only works using variables and i don't know how to do collision detction using a tile map can someone help me pls

Yhanks Wayne

[Adam]

its pretty simple actually.. for one thing.. you don't need the sleep command.. just simply raise the the number of increment.. for example

bally = bally + 2

instead of

bally = bally + 1

[smc44]

yea u can also use a variable for speed for example instead of adding the number 1 or 2 you could dim speed# = 2 and that way you have more abilitys with the propertys of speed# and the # sign is for real numbers decimals, stuff like that

[DJLinux]

96x32
save it as "tilemap.png"

for collision detection the ball should be in center
of the texture and you must know it's radius
32x32
save it as "ball.png" in the same folder

read and learn a litle bit from the code

happy coding

Joshy

' define usefull consts (UPPERCASE)
const FPS          = 50 ' Hz.
const TILEFILE$    = "tilemap.png"
const PLAYERFILE$  = "ball.png"
const MONSTERFILE$ = ""
const RADIUS       = 8 ' radius of the ball in pixel
'
' your first game level
'
data 20,15 ' width x height
data 2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2
data 1,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,1
data 1,0,2,0,2,2,2,2,2,2,2,2,2,2,2,2,2,2,0,1
data 1,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1
data 1,0,2,2,2,2,0,2,2,2,2,2,2,2,2,2,2,2,2,1
data 1,0,1,0,0,1,0,1,0,0,0,1,0,0,0,0,0,1,0,0
data 1,0,1,0,0,1,0,0,0,1,0,0,0,1,0,1,0,1,0,1
data 1,0,0,0,2,2,2,2,2,2,2,2,2,2,0,1,0,1,0,1
data 1,0,1,0,1,0,0,0,0,0,0,0,0,0,0,1,0,1,0,1
data 1,0,1,0,1,0,2,2,2,2,2,2,2,2,0,1,0,1,0,1
data 1,0,1,0,1,0,0,0,1,0,0,0,1,0,0,1,0,1,0,1
data 1,0,1,0,1,0,1,0,0,0,1,0,0,0,1,1,0,1,0,1
data 1,0,2,2,2,2,2,2,2,2,2,2,2,2,2,2,0,1,0,1
data 1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,1
data 2,2,2,2,2,2,2,2,2,2,2,2,2,2,-1,2,2,2,2,2
'
' dim your Vars with "meanfull" names
'
dim xPlayer,yPlayer,xOld,yOld
dim TileCode,nTiles=TexStripFrames(TILEFILE$)
dim Tiles(nTiles-1)=LoadTexStrip(TILEFILE$)
dim wMap,hMap,xMap,yMap
'
' create your levelmap from DATA statments
'
read wMap,hMap
dim LevelMap(wMap-1,hMap-1)
'
' return True if player can move to x/y position 
'
function IsOk(x,y)
  ' x,y are inside the map?
  if (x-RADIUS)<0 or (y-RADIUS)<0 then 
    return FALSE
  end if
  if ((x+RADIUS)/32)>(wMap-1) or ((y+RADIUS)/32)>(hMap-1) then 
    return FALSE
  end if
  yMap=y/32:xMap=(x-RADIUS)/32 ' left
  if LevelMap(xMap,yMap) then return FALSE:end if
  xMap=(x+RADIUS)/32           ' right
  if LevelMap(xMap,yMap) then return FALSE:end if
  yMap=(y-RADIUS)/32:xMap=x/32 ' top
  if LevelMap(xMap,yMap) then return FALSE:end if
  yMap=(y+RADIUS)/32           ' bottom
  if LevelMap(xMap,yMap) then return FALSE:end if
  return True
end function
'
' read the level
'
for yMap = 0 to hMap-1 
  for xMap = 0 to wMap-1
    read TileCode
    ' is it the player start position
    if TileCode=-1 then
      TileCode=0 ' change it back as way texture
      xPlayer=16+xMap*32 ' get xyPlayerStartPosition
      yPlayer=16+yMap*32
    end if
    LevelMap(xMap,yMap)=TileCode 
  next
next
dim TileMap = NewTileMap(Tiles)
SprSetTiles   (LevelMap)
SprSetZorder(1) ' visible under the player and monsters
SprSetParallax(FALSE)
SprSetXRepeat (FALSE)
SprSetYRepeat (FALSE)         
'
' load the ball pink = trancparency
'
SetTexTransparentCol(255,0,255)
dim Player = NewSprite(LoadTex(PLAYERFILE$))
' move sprite origin to center
SprSetXCentre(0.5):SprSetYCentre(0.5)
' begin on start posiion
SprSetPos(xPlayer,yPlayer)
const SPEED=3
TextMode(TEXT_BUFFERED)
'
' main loop
'
While True
  xOld=xPlayer:yOld=yPlayer
  if     ScanKeyDown(VK_LEFT)  then
    xPlayer=xPlayer-SPEED
  elseif ScanKeyDown(VK_RIGHT) then
    xPlayer=xPlayer+SPEED
  elseif ScanKeyDown(VK_UP)    then
    yPlayer=yPlayer-SPEED
  elseif ScanKeyDown(VK_DOWN)  then
    yPlayer=yPlayer+SPEED
  end if
  
  ' handle collision dection only if needed
  if (xOld<>xPlayer) or (yOld<>yPlayer) then
    if IsOK(xPlayer,yPlayer)=True then
      SprSetPos(xPlayer,yPlayer)
    else
      xPlayer=xOld:yPlayer=yOld
    end if
  end if

  ' refresh the screen 
  DrawText()
  ' don't eat all the CPU power 
  WaitTimer(1000/FPS)
wend

---

here the same code but now the player is every time in center of the screen/window
you need only one command SprCameraSetPos(xPlayer-wWin/2,yPlayer-hWin/2)

---

' define usefull consts (UPPERCASE)
const FPS          = 50 ' Hz.
const TILEFILE$    = "tilemap.png"
const PLAYERFILE$  = "ball.png"
const MONSTERFILE$ = ""
const RADIUS       = 8 ' radius of the ball in pixel
'
' your first game level
'
data 20,15 ' width x height
data 2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2
data 1,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,1
data 1,0,2,0,2,2,2,2,2,2,2,2,2,2,2,2,2,2,0,1
data 1,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1
data 1,0,2,2,2,2,0,2,2,2,2,2,2,2,2,2,2,2,2,1
data 1,0,1,0,0,1,0,1,0,0,0,1,0,0,0,0,0,1,0,0
data 1,0,1,0,0,1,0,0,0,1,0,0,0,1,0,1,0,1,0,1
data 1,0,0,0,2,2,2,2,2,2,2,2,2,2,0,1,0,1,0,1
data 1,0,1,0,1,0,0,0,0,0,0,0,0,0,0,1,0,1,0,1
data 1,0,1,0,1,0,2,2,2,2,2,2,2,2,0,1,0,1,0,1
data 1,0,1,0,1,0,0,0,1,0,0,0,1,0,0,1,0,1,0,1
data 1,0,1,0,1,0,1,0,0,0,1,0,0,0,1,1,0,1,0,1
data 1,0,2,2,2,2,2,2,2,2,2,2,2,2,2,2,0,1,0,1
data 1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,1
data 2,2,2,2,2,2,2,2,2,2,2,2,2,2,-1,2,2,2,2,2
'
' dim your Vars here
'
dim xPlayer,yPlayer,xOld,yOld
dim TileCode,nTiles=TexStripFrames(TILEFILE$)
dim Tiles(nTiles-1)=LoadTexStrip(TILEFILE$)
dim wMap,hMap,xMap,yMap
dim wWin=WindowWidth()
dim hWin=WindowHeight()

'
' create your levelmap from DATA statments
'
read wMap,hMap
dim LevelMap(wMap-1,hMap-1)
'
' return True if player can move to x/y position 
'
function IsOk(x,y)
  ' x,y are inside the map?
  if (x-RADIUS)<0 or (y-RADIUS)<0 then 
    return FALSE
  end if
  if ((x+RADIUS)/32)>(wMap-1) or ((y+RADIUS)/32)>(hMap-1) then 
    return FALSE
  end if
  yMap=y/32:xMap=(x-RADIUS)/32 ' left
  if LevelMap(xMap,yMap) then return FALSE:end if
  xMap=(x+RADIUS)/32           ' right
  if LevelMap(xMap,yMap) then return FALSE:end if
  yMap=(y-RADIUS)/32:xMap=x/32 ' top
  if LevelMap(xMap,yMap) then return FALSE:end if
  yMap=(y+RADIUS)/32           ' bottom
  if LevelMap(xMap,yMap) then return FALSE:end if
  return True
end function
'
' read the level
'
for yMap = 0 to hMap-1 
  for xMap = 0 to wMap-1
    read TileCode
    ' is it the player start position
    if TileCode=-1 then
      TileCode=0 ' change it back as way texture
      xPlayer=16+xMap*32 ' get xyPlayerStartPosition
      yPlayer=16+yMap*32
    end if
    LevelMap(xMap,yMap)=TileCode 
  next
next

TextMode(TEXT_BUFFERED)

dim TileMap = NewTileMap(Tiles)
SprSetTiles   (LevelMap)
SprSetZorder(1) ' visible under the player and monsters
SprSetParallax(FALSE)
SprSetXRepeat (FALSE)
SprSetYRepeat (FALSE)         
'
' load the ball pink = trancparency
'
SetTexTransparentCol(255,0,255)
dim Player = NewSprite(LoadTex(PLAYERFILE$))
' move sprite origin to center
SprSetXCentre(0.5):SprSetYCentre(0.5)
' begin on start posiion
SprSetPos(xPlayer,yPlayer)
' set the cam over the player
SprCameraSetPos(xPlayer-wWin/2,yPlayer-hWin/2)

const SPEED=3
TextMode(TEXT_BUFFERED)
'
' main loop
'
While True
  xOld=xPlayer:yOld=yPlayer
  if     ScanKeyDown(VK_LEFT)  then
    xPlayer=xPlayer-SPEED
  elseif ScanKeyDown(VK_RIGHT) then
    xPlayer=xPlayer+SPEED
  elseif ScanKeyDown(VK_UP)    then
    yPlayer=yPlayer-SPEED
  elseif ScanKeyDown(VK_DOWN)  then
    yPlayer=yPlayer+SPEED
  end if
  
  ' handle collision dection only if needed
  if (xOld<>xPlayer) or (yOld<>yPlayer) then
    if IsOK(xPlayer,yPlayer)=True then
    SprCameraSetPos(xPlayer-wWin/2,yPlayer-hWin/2)
      SprSetPos(xPlayer,yPlayer)
      
    else
      xPlayer=xOld:yPlayer=yOld
    end if
  end if

  ' refresh the screen 
  DrawText()
  ' don't eat all the CPU power 
  WaitTimer(1000/FPS)
wend

[DJLinux]

whats up?
where are your AI monsters lol

Joshy

[Wayne Rayner]

Noting much but here is the monster it's pretty crap though i suppose


Monster
which u would have 2 dodge or destroy maybe I don't know
basic4gl.wikispaces.com/file/detail/Monster.PNG

Key
Which unlocks the rock which blocks the finnish line
basic4gl.wikispaces.com/file/detail/Key.png

Rock
which when u have got theey it disappears and the finnish line is availiable
basic4gl.wikispaces.com/file/detail/Rock.png

Finnish Line
Lets u go 2 the next level
basic4gl.wikispaces.com/file/detail/FinnishLine.PNG

-Wayne

PS if ppl think i miss spelt the thread name i didn't it stands for
I need Fucking help with creating a simple maze and i can think of i have learnt heaps from all of u who has helped me so thanks

-wayne

[Wayne Rayner]

Ok everyone since this is my first game project I'm now going to fix it up and make it work.

I will start all over and hopefully get the first level finnished

Wayne Rayner

[OW]

Wait, felp?

[Wayne Rayner]

ok well I mispelled lol.

here this could help you ask dj linux to explain this and it makes your object centre of the screen good for rpg's I think

SprCameraSetPos(xPlayer-wWin/2,yPlayer-hWin/2)

Wayne Rayner

[OW]

Oh, is that for me? Thank you!

Wait, why can't you explain it?

[Wayne Rayner]

This is where I found it from

here the same code but now the player is every time in center of the screen/window
you need only one command SprCameraSetPos(xPlayer-wWin/2,yPlayer-hWin/2)

--------------------------------------------------------------------------------

[OW]

oh ok, cool

Now, about the rest of my cries for help.

[Wayne Rayner]

Jul 14, 2009 21:51:13 GMT -5 OW said:

oh ok, cool

Now, about the rest of my cries for help.

Well I try i'm not so good myself. lol so I can't always help u

[OW]

Oh.

[Wayne Rayner]

But I will always try to help as u sound like u need help